After parting ways, you go and grab a snack. Chewing on a protein bar, your attention wanders briefly around the hideout, naturally settling on Kay and Teddie, who have reconvened over in the lounge area. Kay's crouching down while Teddie explores the structure of the bones protruding from his skin. @{poly_kayk Kay's abrupt retreat still fresh in your mind,|Without thinking,} you drift a few steps in their direction.

"Teddie, have you seen my meds?" Kay asks, rooting through a small overnight bag.

"Check the inside zipper." Teddie suddenly looks dead at you, speaking without breaking eye contact. "$!{aka2}'s here."

*if (cis) 
    @{poly_kayk Kay stiffens for a moment. "Uh—yeah, it's fine!" she tugs|"Yeah? It's fine," Kay replies, tugging} the bag open further with both hands in search of the zipper. "$!{mc_he}@{mc_singular 's|re} cool."

    @{(rel_teddie < 25) "Disagree," says Teddie, staring a hole through you.|"Your call." Teddie shrugs.}

    "Urgh, not in here either," Kay groans, turning her bag over and over. "Where are you hiding, lil meds?"

    Teddie's narrowed-eye glaring [i]dares[/i] you to speak.
    *set rel_teddie %+ 10
    *choice
        #Apologise for intruding.
            *set rel_kay %+ 5
            "Sorry, didn't mean to butt in."

            "What? No, not at all." Kay glances up at you, smiles, then continues frowning into her bag.

            "Go back in the main pocket," Teddie says, coming up on thirty seconds without blinking.

            "I already" — Kay pulls out a pill bottle — "oh. Huh."

            Teddie snorts. "Every time."

            "Shut it." Kay sits back onto the floor with a sigh, then raises the bottle, winking at you. "Delicious estrogen."

            *goto ohkay
        #Ask what the meds are for.
            *set rel_kay %+ 5
            "Are you sick?"

            Kay and Teddie exchange glances. You're struck instantly with dread, the certainty that you've crossed some unseen, unspoken line.

            …Hold on, Teddie's [i]smiling.[/i]

            Kay cracks a grin before breaking into soft giggles. Teddie's smile broadens, but he turns his head away, hiding it.

            @{(expressive > 55) "Want to let me in on the joke here?" you ask, looking between them both.|"Uh…" You're missing the joke here.}

            "Yeah, I've got testosterone poisoning." Kay's expression is mischievous.

            *label ohkay
            Ohhhhhhhh.
            *label ohkay2
            *choice
                #Thank her for telling me: coming out must be daunting.
                    "I'm flattered you'd trust me with this," you say, giving her a smile. "Glad I'm cool enough to earn it."

                    Kay's cheeks redden. "It's not that big of a deal, $!{aka}."

                #I ask if she's been on hormones long.
                    "So, you're on replacement therapy? Is that recent, or…?"

                    Kay shakes her head. "Started in my teens. There were some concerns it'd react weird with my" — she gestures vaguely at her horns and fluff — "but I got the all clear pretty fast. Not as fast as I [i]wanted[/i] but…" she shrugs. "In the past."

                #Demonstrate understanding by mentioning my own gender identity.
                    "I'm cisgender," you say, a touch proudly. Remembered that one from chats with Prii.

                    Kay smothers a laugh in her hand. "You sure are." Dropping her hand, she smiles at you brightly. "Like, genuinely though, good on you for being comfortable with the terms."

                #Check that I haven't made her uncomfortable at any point.
                    "I haven't bothered you at all, have I?" Inadvertently offending her is the last thing you'd want.

                    Kay looks surprised. "Nothing like that! If you had, I probably wouldn't be telling you this."

                    There's a relief.
                    
                #Nod. Alright then. 
                    Fair enough. You don't really have anything to say about that.
                    
                    Kay's face shades towards trepidation, then gradually relaxes.

            "Dion and Mallory don't know. $!{wname} does," Teddie breaks in. You suspect a dire warning is imminent, but Kay talks across him before he can continue.

            *label teddiebreaksin
            "Yeah, but I'm gonna say something soon. Besides, Mal's Mal, and Dion's like super close with them, so you know they're both gonna be fine about it."

            "Just making sure ${mc_he} @{mc_singular knows|know} the deal."

            Kay thumps him lightly on the arm. "I know, you're looking out for me." She grins. "And hey, every girl needs a—"

            "Call me your gay best friend and I'm ramming your horns into the wall."

            "—real good pal to have their back!"
            *choice
                *selectable_if (not (sexualitytalk_teddie)) #...I guess he kind of just came out to me too, huh?
                    Now, is that a sign of trust or does he simply not care?

                    @{(rel_teddie < 25) …Almost definitely the latter.|It's Teddie, could go either way.}

                    *goto teddiecompatible
                *selectable_if (not (sexualitytalk_teddie)) #"You're gay?"
                    "As sunshine," Teddie says it so utterly deadpan that a laugh startles out of you. A slow smile spreads onto his face, and you realise that was entirely deliberate.

                    Turns out the guy [i]does[/i] have a sense of humour.

                    *label teddiecompatible
                    *if (not (compatible_teddie))
                        @{interest_teddie Good thing he brought this up before you said anything awkward, huh?|Well, it's good to know.}

                    *else
                        @{interest_teddie You ignore the small corner of your mind enthusing over the confirmation of your compatibility.|Well, it's good to know.}

                #Commiserate with Teddie over being the queer friend.
                    *set rel_teddie %+ 7
                    "I've been there too."

                    Teddie seems taken aback to be addressed. "S'fine." He glances at Kay and half-smiles. "She's just a brat."

                    She presses a hand to her chest. "Ow, alright."

                    Your own smile is tempered by a pang of longing. That was one of the neat things about AdVenture; you all had your queerness in common. It didn't matter if the particulars were different, there was a shared bond.

                #"I doubt Dion would appreciate you ruining the décor."
                    "Yeah, Teddie, think of the insurance premiums!"

                    He snorts. "Sure. We definitely have those."

                    @{(expressive > 55) You put on an over-enthusiastic voice. "Remember, when villains come to town, you've got a hero in Riviera-Brown!"|"Imagine getting caught because you claimed on heroes raiding your hideout," you muse.}

                    @{(expressive > 55) Kay groan laughs. "I haven't thought about that oldass commercial in years, and now the stupid jingle's gonna be stuck in my head. Thanks, $!{aka}."|"That's happened before, pretty sure," says Kay. "This villain's car got totalled and he tried to take it to the garage, and it turned out a hero worked there for their day job."}

                    @{(expressive > 55) You wink. "You're welcome."|Teddie makes a small noise of consternation. "I've told you that story is fake. A villain got caught because their car got trashed and the cops found ID in the wreck. People just made up that other bullshit." }

                    @{(expressive > 55) "They're just RB Insurance now," says Teddie. "Had to rebrand when their execs got caught bribing masks to fight around uninsured buildings."|"Such a killjoy," Kay sighs. Teddie catches your eye and then rolls his own. Huh. Is he warming up to you?}

                    @{(expressive > 55) Scumbag insurers? Some things never change.|} 

                #I'm a little envious of their connection.
                    The relaxed ease they have with one another reminds you of what you've lost. You and @{bestie Beth|Prii|Shauna|Grant|DUMMY} were like that.

                    *if bestie = 2
                        Prii… it's impossible to think about them without that horrible spectre leering into your memories, sending you back to that cell.

                    *elseif bestie =1
                        @{ephalanx Beth. Who's still alive. Who's a hero and a Hound. Who you fought. Fuck.|Beth... where is she now?}

                    *else
                        @{(bestie = 3) It's weird to think about Shauna in the context of a bunch of supervillains, but she'd have liked Kay and Wil, you think.|You get lost a moment, imagining the chaotic energy Grant and Mal would bring to a conversation. Oh man, and Teddie would have hated him.}

            *set gendertalk_kay true
            *set sexualitytalk_teddie true
            *if (not (compatible_teddie))
                 *set romance_teddie 1
                 *set interest_teddie false
                 *set flirt_teddie 0

            There's a lull in the conversation while Kay takes her meds and Teddie, frowning, starts to poke again at sections of exposed bone.

            *choice
                *if (aro != 4) #Kay's trust is stirring emotions of a kind I don't care to admit. @{ftone [Flirt, passive]|}
                    *set interest_kay true
                    *set flirt_kay +1
                    She's a sweet person, being so open, taking that leap of faith. Courageous, too. Nothing's forcing her to tell you about herself, and she's doing it anyway.

                    *label certainwarmth
                    A certain warmth has settled in your chest, @{(aro = 3) and you're already fending off the urge to drop a flirtatious overture or two|one you know has potential to take root and sprout into greater feelings. Greater, oh-so-complicated feelings.}

                    *label deepandquiet
                    You take a deep and quiet breath, nudging your emotions into the background. This isn't the time.

                *if ((not (cis)) and (aro !=4)) #Finding more common ground with Kay isn't making this crush any better. @{ftone [Flirt, passive]|}
                    @{interest_kay You've been nursing more-than-just-teammate feelings for Kay regardless, but a fresh point of connection only deepens the emotions.|Wait. Shit. Did you really just think that? Are you crushing on her? Dammit.}

                    *set interest_kay true
                    *set flirt_kay +1

                    *goto certainwarmth
                *if ((aro != 4) and (romance_teddie !=1)) #@{t_teddie I suddenly catch myself daydreaming about Teddie like some kind of idiot.|The more I get to know Teddie, the more I'm drawn to him.} @{ftone [Flirt, passive]|}
                    He's trusting you, despite being so protective of Kay. @{t_teddie You picture him smiling and moving in close. There's that unusually soft look in his eyes as you share his presence and—Good fucking grief why are you like this? Apparently, one civil conversation is enough to make you forget he's an abrasive jackass and start mooning after him like a teenager with their first crush. Get it together, $!{forename}.|It's a vulnerability, the first of its kind. Perhaps the very beginnings of letting you in past his walls. Hard to be sure.}

                    @{(rel_teddie < 30) Can't forget you aren't on the greatest terms with the guy. Probably shouldn't get your hopes up. Or otherwise, get ready to do a lot of work digging yourself out of the hole. |You think he—maybe [i]likes[/i] you is too strong a term, but he's streets ahead from how he treated you when you first met. Hopefully, you can nurture that growing closeness.}

                    Surprise surprise, Teddie's making things complicated.

                    *goto deepandquiet
                #Take a closer look at Teddie's growths.
                    Everywhere the bones have broken through Teddie's skin, the surrounding flesh is both ragged and puckered, and thin pink lines that could be scarring crisscross his body. it occurs to you that you've never seen a trace of blood on him, despite what should be various open wounds. His power must prevent the growths from actually injuring him.

                    Though, looking at the tight grimace he wears while worrying at his arm, it's clear that not causing injury is rather different from painless.

                    Teddie's eyes shift and he catches you looking. Immediately releasing his grip on the angular spur, he scowls and averts his gaze, closing off completely.

                #Inspect Kay's horns and woolly hair.
                    Sans a careful morning routine, Kay's hair  sticking out at all kinds of odd angles, disrupting its usual careful framing around her horns. It's only now that you're seeing the grey-white tufts all askew that it you begin to understand what an ordeal wrangling her mop under control must be. @{natural You've got experience managing unruly hair yourself, and although the texture of Kay's looks very different to your own, you can picture the struggles of maintaining it.|That tight, woolly mass looks like the kind of place that hairbrushes go to die.}

                    The horns are on another level, almost impossible to hide. You suspect most attempts would only call attention to them, or else make Kay look incredibly suspicious to anyone with eyes. Even with your own share of challenges, you don't envy so blatant a signal of parahumanity.

                    Kay's eyes flick up and she catches you looking. Her hand immediately and self-consciously goes up to her horns, and you avert your gaze, feeling vaguely guilty.

                #Keep my eyes to myself.
                    You wouldn't want those two gawking at @{feature your lifeless hair;|those unnatural eyes of yours;|the markings on your shoulders;|your twisted abdominal decoration;} you mind your own business until Kay's finishes washing the meds down with water.

                    She catches your eye and winks. "Love me some girl candy." @{interest_kay Is it your imagination, or did she say that with a certain suggestive inflection?|}

            You're able to simply idle pleasantly in their company for a few minutes, but internally you acknowledge that you're going to need to make tracks soon. Too much to do.
            
            With a quiet farewell, you get back to business.

            *return   
        #Marvel that she's pulling off all these stunts while ill.
            *set expressive %+ 10
            *set rel_kay %+ 5
            "If you've been sick these last couple missions, then you must be a force of nature healthy."

            Kay bursts out into full throated laughter before clapping her hands to her mouth, looking deeply embarrassed.

            Baffled, you look between her and Teddie, and have to double take as you realise that Teddie's [i]smirking[/i].

            "Not… not that kind of meds, $!{aka}," Kay manages, valiantly struggling against further fits of laughter. "It's estrogen."

            Ah. Heat rushes to your face.

            Mm. Well. This one's going into the album of embarrassing moments for your brain to replay at 3am.

            *goto ohkay2
        #Staring match.
            *set rel_teddie %+ 5
            You don't back down, meeting Teddie's eyes with your own hard stare.

            He straightens to full height and intensifies his glower.

            Twenty full seconds of intense glaring go by, and then an exasperated raspberry startles you both out of it.

            Kay, of course, is the culprit, and she makes a show of rolling her eyes as soon as she's sure she has your attention. "You two are ridiculous."

            You and Teddie exchange glances, there's an ever-so-slight, ever-so-sheepish smile on his face.

            "Did you find it?" you ask her.

            "Changing the subject, huh?" Kay jibes, then grins, holding up a pill bottle. "Yeah. Delicious estrogen."

            *goto ohkay
        #I have no idea what to say.
            *set rel_teddie %+ 5
            Nothing it is!

            You keep your mouth shut as Kay continues to rummage, maintaining a running commentary all the while. With glacial speed, Teddie's accusing expression softens. He gives you the tiniest of nods.

            "Aha!" Kay announces, holding aloft a bottle of pills. "Delicious estrogen."

            *goto ohkay

*else
    @{poly_kayk Kay stiffens for a moment. "Uh—yeah, it's fine!" she tugs|"Yeah? It's fine," Kay replies, tugging} the bag open further with both hands in search of the zipper. "I'm pretty sure ${mc_he} @{mc_singular gets|get} it."

    "Why?"

    Kay breaks off her search to look at you, then Teddie. She shrugs. "I dunno. Vibes." You tilt your head in question, and she continues. "Y'know, traded in your gender for the cool new model. Those vibes."

    Well, there you go. Just as you've been picking up on little things—her self-consciousness around her voice and laugh—and trying to figure her out, Kay's been doing the same to you. The good old fashioned 'is this person queer or am I projecting?' dance.

    Regardless…
    *set rel_kay %+ 10
    *choice
        #I can safely say I've never heard anyone describe being trans in that way.
            "That's a new one on me," you say, and Kay grins.

            "I'm very creative, I know," she boasts, then pauses, studying your face. You recognise the hesitant, questioning look in her eyes; she's made the first vulnerable move, is on tenterhooks for your response.

            Leaving her to worry would feel wrong. You give her a slight nod. 

            Another grin, this tinged with relief. "Probably kinda ironic to call this a safe space considering all the crime we get up to, but it's nice having other people around who understand."

            "No arguments here," you reply. On both counts, actually.

        #I'm kind of mad I didn't think of it first.
            "Stealing that," you announce.

            "My gender? Get your own," she quips back, grinning.

            "Already did," you drawl, and she laughs.

            "Yeah, okay, guess I walked into that one."

        #There's a hard knot in my stomach, I haven't talked about identity in a while.
            Familiar anxieties about passing and not presenting in the 'right' way bubble up to the surface. You drop your eyes and shuffle your feet.

            Kay picks up on your mood instantly. "Sorry, is it a bad subject? I didn't mean to upset you."

            "It's okay," you say quietly. "Out of practice, I guess."

            Kay's voice stays soft, gentle. "Acknowledge the irony of saying this considering all the crime we get up to, but you're in safe company. There's me, @{(wgender ="nonbinary") there's Mal and Wil, I'm sure Dion's cool,|there's Mal, Wil's cool about gender stuff,} and this dork" — she thumps Teddie in the arm, earning a monotone 'ow' — "is just absolutely the best."

            Slowly, you nod, though your feelings remain mixed, a complicated tangle. It's hard to rebuild your comfort on the topic. 

        #"I wondered, but I didn't want to say anything."
            Kay nods. "Same. Was getting…" she wiggles her fingers. "Signals. Radio trans."

            You smile at the pantomime. @{(expressive > 55) "Trans FM, coming at you live with the hottest new takes on gender."|"Glad to share a wavelength, then."}

            Kay beams. Teddie snorts. @{(expressive > 55) "Better you DJing than her. Kay's taste in music sucks."|"Wouldn't say that if you knew her taste in music."}

            The unprovoked assault on her auditory opinions wipes off Kay's smile. She harrumphs, hands on her hips. "Can it, token cis."

            "That's your only defence?" His mouth twitches up. "Proves my point."

            You hide a laugh in your hand. It's… nice, being around your kind of people. You hadn't realised—or maybe closed yourself off from—how much you missed it.

        *selectable_if ((mc_gender = "Agender") or (mc_gender = "None")) #"More like traded it for a soda and a 50% off coupon."
            A laugh of pure delight bubbles out of Kay. "I guess you don't really do the gender thing, huh?"

            You shrug and smile. She grins from ear to ear, and you think you see a slight smile from Teddie, even.


    *page_break
    At least this is a secret you can share. Diversity win, this supervillain team is@{(wgender = "nonbinary")  over|} fifty percent gender anarchist. 

    [i]"Why don't you introduce yourself? You aren't a subject any longer; it's important they all know what to call you." There's a glint in his eye, a flash behind his glasses. "What kind of scientist would I be if I allowed the incorrect labels?"[/i]

    You slam that box of memories and lock it tight. That was never about your pronouns; it was a powerplay, a trap. Hypothesis wanted you to call yourself Paradigm, the gender identity— 

    What part of 'locked tight' is your brain failing to grasp? You push the thoughts even further into their darkened corner. You aren't letting them, letting [i]him[/i] taint a pleasant, affirming conversation.

    The good news is that Teddie's on hand to provide a distraction. Though perhaps that's also part of the bad news. "Dion and Mallory don't know. $!{wname} does," he says. He looks about to deliver a dire warning, but Kay talks across him before he can continue.

    *goto teddiebreaksin